/* dbug.i dps 09/12/07
   USAGE:
     /* where mode is 0 = off, 1 = display on, 2 = file on, 3 = timing on */
     {c:\dbug.i mode {&FILE-NAME} {&LINE-NUMBER}
                "/* a comment */"
                var1
                var2
                "AVAIL var3"
     }
*/

&GLOBAL-DEFINE dbugFileName 'c:\temp\dbug' + STRING(YEAR(TODAY),'9999') ~
                            + STRING(MONTH(TODAY),'99') + STRING(DAY(TODAY),'99') + '.txt'

&IF {1} = 1 &THEN
  /* IF USERID(LDBNAME(1)) = 'username' THEN */ DO:
    &MESSAGE Debug statements exist in {2} line {3}.
    OUTPUT TO TERMINAL.

    IF /* SESSION:APPL-ALERT-BOXES */ TRUE THEN DO:
      MESSAGE 'At' PROGRAM-NAME(2) IF VALID-HANDLE(SELF) THEN SELF:NAME ELSE '' 'Line' {3} SKIP
        '{4}'  {4}  SKIP '{5}'  {5}  SKIP '{6}'  {6}  SKIP
        '{7}'  {7}  SKIP '{8}'  {8}  SKIP '{9}'  {9}  SKIP
        '{10}' {10} SKIP '{11}' {11} SKIP '{12}' {12} SKIP
        '{13}' {13} SKIP '{14}' {14} SKIP '{15}' {15} SKIP
        '{16}' {16} SKIP '{17}' {17} SKIP '{18}' {18} SKIP
        '{19}' {19} SKIP '{20}' {20} SKIP '{21}' {21} SKIP
        '{22}' {22} SKIP '{23}' {23}
        VIEW-AS ALERT-BOX INFORMATION.
    END.
    ELSE DO:
      MESSAGE 'At' PROGRAM-NAME(2) SELF:NAME 'Line' {3}
        '{4}'  {4}  '{5}'  {5}  '{6}'  {6}
        '{7}'  {7}  '{8}'  {8}  '{9}'  {9}
        '{10}' {10} '{11}' {11} '{12}' {12}
        '{13}' {13} '{14}' {14} '{15}' {15}
        '{16}' {16} '{17}' {17} '{18}' {18}
        '{19}' {19} '{20}' {20} '{21}' {21}
        '{22}' {22} '{23}' {23}.
      PAUSE.
    END.

    OUTPUT CLOSE.
  END.
&ELSEIF {1} = 2 OR {1} = 3 &THEN
  /* IF USERID(LDBNAME(1)) = 'username' THEN */ DO:
    &MESSAGE Debug statements exist in {2} line {3}.
    &IF {1} = 3 &THEN IF SEARCH({&dbugFileName}) = ? THEN ETIME(TRUE). &ENDIF

    OUTPUT TO VALUE({&dbugFileName}) APPEND. 
    PUT UNFORMATTED 'At ' PROGRAM-NAME(2) ' ' SELF:NAME ' Line ' {3} ' @ ' STRING(TIME,'HH:MM:SS').
    &IF {1} = 3 &THEN PUT UNFORMATTED ' ' ETIME ' ms'. &ENDIF
    PUT UNFORMATTED SKIP.
    IF '{4}'  <> '' THEN PUT UNFORMATTED '{4} '  {4}  SKIP.
    IF '{5}'  <> '' THEN PUT UNFORMATTED '{5} '  {5}  SKIP.
    IF '{6}'  <> '' THEN PUT UNFORMATTED '{6} '  {6}  SKIP.
    IF '{7}'  <> '' THEN PUT UNFORMATTED '{7} '  {7}  SKIP.
    IF '{8}'  <> '' THEN PUT UNFORMATTED '{8} '  {8}  SKIP.
    IF '{9}'  <> '' THEN PUT UNFORMATTED '{9} '  {9}  SKIP.
    IF '{10}' <> '' THEN PUT UNFORMATTED '{10} ' {10} SKIP.
    IF '{11}' <> '' THEN PUT UNFORMATTED '{11} ' {11} SKIP.
    IF '{12}' <> '' THEN PUT UNFORMATTED '{12} ' {12} SKIP.
    IF '{13}' <> '' THEN PUT UNFORMATTED '{13} ' {13} SKIP.
    IF '{14}' <> '' THEN PUT UNFORMATTED '{14} ' {14} SKIP.
    IF '{15}' <> '' THEN PUT UNFORMATTED '{15} ' {15} SKIP.
    IF '{16}' <> '' THEN PUT UNFORMATTED '{16} ' {16} SKIP.
    IF '{17}' <> '' THEN PUT UNFORMATTED '{17} ' {17} SKIP.
    IF '{18}' <> '' THEN PUT UNFORMATTED '{18} ' {18} SKIP.
    IF '{19}' <> '' THEN PUT UNFORMATTED '{19} ' {19} SKIP.
    IF '{20}' <> '' THEN PUT UNFORMATTED '{20} ' {20} SKIP.
    IF '{21}' <> '' THEN PUT UNFORMATTED '{21} ' {21} SKIP.
    IF '{22}' <> '' THEN PUT UNFORMATTED '{22} ' {22} SKIP.
    IF '{23}' <> '' THEN PUT UNFORMATTED '{23} ' {23} SKIP.
    PUT SKIP(1).
    OUTPUT CLOSE.

    &IF {1} = 3 &THEN ETIME(TRUE). &ENDIF
  END.
&ENDIF

/* end of include */