/*--------------------------------------------------------------------------
----
  Purpose:  Send Mail using Microsoft Outlook

  Parameters:    

    RUN kb/util/SendMail.p
      (INPUT TRUE/FALSE,                                  /* Ask Login */
       INPUT "MS Exchange Settings" or BLANK for default, /* Profile Name */
       INPUT 2,                                           /* Priority
High=2, Low = 0 */
       INPUT "MAPI Test",                                 /* Subject */
       INPUT "This is a test.",                           /* Message */
       INPUT "gkharbanda@kbyte.net,gkharbanda@kbyte.net", /* Send To */
       INPUT "c:\gulshan\check.bmp").                     /* Attachment */

  Notes:       
        Last change:  GK   15 Dec 2000    4:39 pm
----------------------------------------------------------------------------
--*/
/* Input parameters */
DEF INPUT PARAMETER iAskLogin  AS LOGICAL NO-UNDO.
DEF INPUT PARAMETER cProfile   AS CHAR NO-UNDO.
DEF INPUT PARAMETER iPriority  AS INT  NO-UNDO.
  /* Low = 0; Normal = 1; High = 2 */
DEF INPUT PARAMETER cSubject   AS CHAR NO-UNDO.
DEF INPUT PARAMETER cText      AS CHAR NO-UNDO.
DEF INPUT PARAMETER cTo        AS CHAR NO-UNDO.
DEF INPUT PARAMETER cFiles     AS CHAR NO-UNDO.

/* Variables */
DEF VAR chSession AS COM-HANDLE NO-UNDO.
DEF VAR chMessage AS COM-HANDLE NO-UNDO.
DEF VAR chRecip   AS COM-HANDLE NO-UNDO.
DEF VAR chFiles   AS COM-HANDLE NO-UNDO.

DEF VAR iLoop AS INT NO-UNDO.

/* Connection */
CREATE "MAPI.SESSION" chSession.
chSession:Logon(cProfile,,iAskLogin,FALSE).

/* Message Creation */
ASSIGN
    chMessage            = chSession:OutBox:Messages:Add()
    chMessage:Subject    = cSubject
    chMessage:Text       = cText
    chMessage:importance = iPriority.

/* Send To */
DO iLoop = 1 TO NUM-ENTRIES(cTo):
    ASSIGN
        chRecip      = chMessage:Recipients:Add()
        chRecip:Name = ENTRY(iLoop, cTo)
        chRecip:Type = 1.

    chRecip:Resolve.
END.

/* Attachments */
IF cFiles <> "" THEN
DO iLoop = 1 TO NUM-ENTRIES(cFiles):
    ASSIGN
        chMessage:Text = chMessage:Text + CHR(10)
        chFiles        = chMessage:Attachments:ADD()
        chFiles:name   = ENTRY(iLoop, cFiles)
        chFiles:source = ENTRY(iLoop, cFiles).
END.

/* Send message */
chMessage:Update(TRUE, TRUE).
chMessage:Send(TRUE, FALSE).
chSession:Logoff.

/* Release Objects */
RUN ReleaseObjects.

PROCEDURE ReleaseObjects:
/*--------------------------------------------------------------------------
----
  Purpose:     
  Parameters:  <none>
  Notes:       
----------------------------------------------------------------------------
--*/
    RELEASE OBJECT chRecip NO-ERROR.
    RELEASE OBJECT chMessage NO-ERROR.
    RELEASE OBJECT chSession NO-ERROR.
    IF cFiles > "" THEN RELEASE OBJECT chFiles NO-ERROR.
END PROCEDURE.